EtherCAT CiA 402 User Manual

2025.12.30, EtherCAT CiA 402 v1.2.

You can download the EtherCAT CiA 402 User Manual file ここ.

1. 概要

1.1  About QEC MainDevice (MDevice)

QEC MDevice is an EtherCAT MDevice compatible with 86Duino Coding IDE 501+. It offers real-time EtherCAT communication between the EtherCAT MDevice and the EtherCAT SubDevice. Except for the EtherCAT Library of 86Duino IDE, QEC MDevice also provides Modbus, Ethernet TCP/IP, CAN bus, etc., industrial communication protocols, and uses a rich high-level C/C++ programming language for rapid application development.

For additional QEC and EtherCAT details, please refer to the EtherCAT ライブラリ API ユーザーマニュアル.

1.1.1  What is 86Duino IDE?

86Duino統合開発環境（IDE）ソフトウェアを使えば、86DuinoボードとQEC Mainデバイスへのコード記述とアップロードが簡単に行えます。Windows、Mac OS やLinuxで動作します。この環境はJavaで記述されており、Arduino IDE、Processing、DJGPPなどのオープンソースソフトウェアをベースにしています。これらのソフトウェアは以下からダウンロードできます。 https://www.qec.tw/software/.

QEC MDevice’s software, 86Duino IDE, also offers a configuration utility: 86EVA, a graphic user interface tool for users to edit parameters for the EtherCAT network; its functions are as follows:

• EtherCAT SubDevice scanning
• ENIファイルのインポート
• EtherCAT Mainデバイスの設定
• Configure EtherCAT SubDevice

For additional details, please refer to the 86EVA User Manual.

1.2 About EthercatDevice_CiA402

EthercatDevice_CiA402 is a generic CiA 402 EtherCAT SubDevice class designed to control any EtherCAT servo drive that supports the CiA 402 standard.
一般的に使用される CiA 402 オブジェクトへのアクセス機能と、次のようないくつかの CiA 402 操作モードおよび機能グループの操作機能を提供します。

• Operation Modes
  • Profile Position (pp)
  • Profile Velocity (pv)
  • Profile Torque (tq)
  • Homing (hm)
  • Cyclic Synchronous Position (csp)
  • Cyclic Synchronous Velocity (csv)
  • Cyclic Synchronous Torque (cst)
• Function Groups
  • Touch Probe

Implementation Directive for CiA402 Drive Profile.
Directive for using IEC 61800-7-201 within EtherCAT-based servo drives.

CiA 402 の詳細については、次のドキュメントを参照してください。

• CiA Draft Standard 402: CiA® 402-CANopen Drives and Motion Control Profile.
• ETG.6010 Implementation Directive for CiA402 Drive Profile
• 現在使用されているCiA 402ドライブデバイスのユーザーマニュアル

EthercatDevice_CiA402 のクラス関係は次の図に示されています。

• EthercatDevice_CiA402 inherits from _EthercatDevice_CommonDriver.

For more detailed information about EtherCAT Device Class, please refer to EtherCAT Library API  User Manual – QEC.

1.2.1  Drives and Motion Control

The device control function block controls all functions of the drive (drive function and power section). It is divided into device control of the state machine and the operation mode function.

The controlword can control the state of the drive.
The state of the drive is shown in the statusword.

In remote mode, the device is controlled directly from the CANopen network by PDO and SDO.

The state machine is controlled externally by the controlword and external signals. The write access to the controlword is controlled by the optional hardware signal ‘Remote’. The state machine is also controlled by internal signals like faults and modes of operation.

1.2.2 State machine

The state machine describes the device status and the possible control sequence of the drive. A single state represents a special internal or external behavior. The state of the drive also determines which commands are accepted. E.g. it is only possible to start a point-to-point move when the drive is in state OPERATION ENABLE.

States may be changed using the controlword and/or according to internal events. The current state can be read using the statusword.

State Description

Notes:

• If a command is received that causes a change of state, this command must be processed completely and the new state attained before the next command can be processed.
• ‘Drive function is disabled’ implies no energy is supplied to the motor. This may be achieved by different manufacturers in different ways. Reference values are not processed.
• ‘Drive function is enabled’ implies that energy can be supplied to the motor. The reference values (torque, velocity, position) are processed.
• ‘Fault occurred’ implies that a fault in the drive has occurred. In this case, there is a transition to the state FAULT REACTION ACTIVE. In this state the device will execute a special fault reaction. After the execution of this fault reaction, the device will switch to the state FAULT. This state can only be left by the command ‘Fault Reset’, but only if the fault is not active anymore.

2. 関数

2.1 Initialization-related Functions

Initialization-related functions for the EthercatDevice_CiA402 class.
Functions:

• attach()
• detach()
• isStepper()

2.2 Control-related Functions

Control-related functions for the EthercatDevice_CiA402 class.
Functions:

• getCiA402Mode()
• setCiA402Mode()
• getCiA402State()
• setCiA402State()
• enable()
• disable()

2.3 Operation-related Functions

Operation-related functions for the EthercatDevice_CiA402 class.
Functions:

• setTargetPosition()
• setTargetVelocity()
• setTargetTorque()
• setProfileAcceleration()
• setProfileDeceleration()
• setMaxAcceleration()
• setMaxDeceleration()
• setMaxProfileVelocity()
• setMotionProfileType()
• setPositionWindow()
• setPositionWindowTime()
• setPositionOffset()
• setSoftwarePositionLimit()
• setFollowingErrorWindow()
• setPositionPolarity()
• setVelocityWindow()
• setVelocityWindowTime()
• setVelocityThreshold()
• setVelocityOffset()
• setMaxMotorSpeed()
• setVelocityPolarity()
• setTorqueOffset()
• setMaxTorque()
• setPositiveTorqueLimit()
• setNegativeTorqueLimit()
• setQuickStopDeceleration()
• setQuickStopOptionCode()
• setShutdownOptionCode()
• setDisableOperationOptionCode()
• setHaltOptionCode()
• setFaultReactionOptionCode()
• getErrorCode()
• getSupportedDriveModes()
• getMotorResolution()
• getPositionActualValue()
• getVelocityActualValue()
• getTorqueActualValue()
• getCurrentActualValue()
• getPositionDemandValue()
• getPositionDemandInternalValue()
• getPositionActualInternalValue()
• getAdditionalPositionActualValue()
• getFollowingErrorActualValue()
• getVelocityDemandValue()
• getTorqueDemandValue()
• getDigitalInputs()

2.4 Profile Position mode (pp) Related Functions

Profile Position mode (pp) related functions for the EthercatDevice_CiA402 class.
Functions:

• pp_SetVelocity()
• pp_SetAcceleration()
• pp_SetDeceleration()
• pp_SetMotionProfileType()
• pp_Run()
• pp_IsTargetReached()
• pp_CheckFollowingError()
• pp_Halt()
• pp_Resume()

2.5 Profile Velocity mode (pv) Related Functions

Profile Velocity mode (pv) related functions for the EthercatDevice_CiA402 class.
Functions:

• pv_SetAcceleration()
• pv_SetDeceleration()
• pv_SetMotionProfileType()
• pv_Run()
• pv_IsTargetReached()
• pv_CheckZeroSpeed()
• pv_CheckMaxSlippageError()
• pv_Halt()
• pv_Resume()

2.6 Profile Torque mode (tq) Related Functions

Profile Torque mode (tq) related functions for the EthercatDevice_CiA402 class.
Functions:

• tq_SetTorqueSlope()
• tq_SetTorqueProfileType()
• tq_SetMotorRatedCurrent()
• tq_SetMotorRatedTorque()
• tq_Run()
• tq_IsTargetReached()
• tq_Halt()
• tq_Resume()

2.7 Homing mode (hm) Related Functions

Homing mode is the process by which a drive seeks the home position, also referred to as the datum, reference point, or zero point. This ensures that the motor starts from a known and repeatable position.

Homing can be achieved through various methods, typically using limit switches at the ends of travel or a home switch (zero point switch) in mid-travel. Many homing methods also utilize the index (zero) pulse train from an incremental encoder for precise positioning.

Homing mode (hm) related functions for the EthercatDevice_CiA402 class.
Functions:

• hm_SetHomeOffset()
• hm_SetHomingMethod()
• hm_SetHomingSpeeds()
• hm_SetHomingAcceleration()
• hm_Run()
• hm_IsAttained()
• hm_Stop()

2.8 Function Group “Touch Probe” Related Functions

Touch Probe related functions for the EthercatDevice_CiA402 class.
Functions:

• enableTouchProbe1()
• enableTouchProbe2()
• disableTouchProbe1()
• disableTouchProbe2()
• isTouchProbe1ValueReady()
• isTouchProbe2ValueReady()
• readTouchProbe1Value()
• readTouchProbe2Value()

2.9 Low-level functions for mode-specific flow control

Low-level functions for mode-specific flow control related functions for the EthercatDevice_CiA402 class.
Functions:

• setHaltBit()
• isTargetReached()
• setModeSpecificBit4()
• setModeSpecificBit5()
• setModeSpecificBit6()
• checkModeSpecificBit12()
• checkModeSpecificBit13()

3. Example

3.1 Profile Position (pp) control

Implement position control on a CiA 402 EtherCAT SubDevice supporting Profile Position mode (pp).

• Move a relative distance of 10,000 units in the positive direction.
• Move a relative distance of 10,000 units in the negative direction.

Here is the example code.

#include "Ethercat.h" 

EthercatMaster master;
EthercatDevice_CiA402 motor; 

void setup() {
  master.begin(); 
  motor.attach(0, master);
  motor.setCiA402Mode(CIA402_PP_MODE);
  master.start();
  
  motor.enable();
  motor.pp_SetMotionProfileType(0);
  motor.pp_SetVelocity(100000);
  motor.pp_SetAcceleration(5000);
  motor.pp_SetDeceleration(5000); 
} 

void loop() {
  motor.pp_Run(100000, CIA402_PP_RELATIVE, true); 
  while (motor.pp_IsTargetReached() == 0);
  motor.pp_Run(-100000, CIA402_PP_RELATIVE, true); 
  while (motor.pp_IsTargetReached() == 0); 
}

3.2 Profile Position (pp) control in cyclic callback

Implement position control on a CiA 402 EtherCAT SubDevice supporting Profile Position mode (pp) in cyclic callback.

• Move a relative distance of 10,000 units in the positive direction.
• Move a relative distance of 10,000 units in the negative direction.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 607Ah: Target position
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 6064h: Position actual value

Here is the example code.

#include "Ethercat.h" 

EthercatMaster master;
EthercatDevice_CiA402 motor; 

#define STATE_SET_COMMAND (0)
#define STATE_CHECK_ACK_SET (1)
#define STATE_CHECK_ACK_CLEAR (2)
#define STATE_WAIT_TARGET_REACHED (3)
int state = STATE_SET_COMMAND;
int toggle = 0;

void MyCyclicCallback() 
{
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED) 
    return;
  
  switch (state) { 
    case STATE_SET_COMMAND:
      toggle = !toggle;
      motor.setTargetPosition(100000 * toggle - 100000 * !toggle);
      motor.setModeSpecificBit6(true);
      motor.setModeSpecificBit5(false);
      motor.setModeSpecificBit4(true);
      state = STATE_CHECK_ACK_SET;
      break;
    case STATE_CHECK_ACK_SET:
      if (motor.checkModeSpecificBit12()) {
        motor.setModeSpecificBit4(false); 
        state = STATE_CHECK_ACK_CLEAR; 
      } 
      break; 
    case STATE_CHECK_ACK_CLEAR:
      if (motor.checkModeSpecificBit12() == 0) 
        state = STATE_WAIT_TARGET_REACHED;
      break;
    case STATE_WAIT_TARGET_REACHED:
      if (motor.pp_IsTargetReached())
        state = STATE_SET_COMMAND; 
      break;
  } 
} 

void setup() {
  master.begin();
  
  motor.attach(0, master); 
  motor.setCiA402Mode(CIA402_PP_MODE);
  
  /* RxPDO mapping configuration. */
  motor.sdoDownload8(0x1C12, 0x00, 0); 
  motor.sdoDownload8(0x1601, 0x00, 0); 
  motor.sdoDownload32(0x1601, 0x01, 0x60400010);
  motor.sdoDownload32(0x1601, 0x02, 0x607A0020);
  motor.sdoDownload8(0x1601, 0x00, 2);
  motor.sdoDownload16(0x1C12, 0x01, 0x1601);
  motor.sdoDownload8(0x1C12, 0x00, 1);
  /* TxPDO mapping configuration. */
  motor.sdoDownload8(0x1C13, 0x00, 0);
  motor.sdoDownload8(0x1A01, 0x00, 0); 
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010);
  motor.sdoDownload32(0x1A01, 0x02, 0x60640020); 
  motor.sdoDownload8(0x1A01, 0x00, 2); 
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01); 
  motor.sdoDownload8(0x1C13, 0x00, 1);
  master.attachCyclicCallback(MyCyclicCallback);
  master.start();
  
  motor.enable();
  motor.pp_SetMotionProfileType(0); 
  motor.pp_SetVelocity(100000);
  motor.pp_SetAcceleration(5000);
  motor.pp_SetDeceleration(5000); 
} 

void loop() {
  // ... 
}

3.3 Profile Velocity (pv) control

Implement velocity control on a CiA 402 EtherCAT SubDevice supporting Profile Velocity mode (pv).

• Move in the positive direction at a speed of 1,000 units per second for 3 seconds.
• Move in the negative direction at a speed of 1,000 units per second for 3 seconds.

Here is the example code.

#include "Ethercat.h"

EthercatMaster master; 
EthercatDevice_CiA402 motor; 

void setup() {
  master.begin();
  motor.attach(0, master);
  motor.setCiA402Mode(CIA402_PV_MODE);
  master.start();
  
  motor.enable(); 
  motor.pv_SetMotionProfileType(0);
  motor.pv_SetAcceleration(5000);
  motor.pv_SetDeceleration(5000);
} 

void loop() {
  motor.pv_Run(1000); 
  while (motor.pv_IsTargetReached() == 0);
  delay(3000); 
  
  motor.pv_Run(-1000);
  while (motor.pv_IsTargetReached() == 0);
  delay(3000);
}

3.4 Profile Velocity (pv) control in cyclic callback

Implement velocity control on a CiA 402 EtherCAT SubDevice supporting Profile Velocity mode (pv).

• Move in the positive direction at a speed of 1,000 units per second for 3 seconds.
• Move in the negative direction at a speed of 1,000 units per second for 3 seconds.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 60FFh: Target velocity
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 606Ch: Velocity actual value

Here is the example code.

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_CiA402 motor; 

int toggle = 0;
int cycle_count = 3000; 

void MyCyclicCallback()
{ 
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED)
    return;
  
  if (++cycle_count < 3000)
    return;
  
  cycle_count = 0; 
  toggle = !toggle; 
  motor.setTargetVelocity(1000 * toggle - 1000 * !toggle);
} 

void setup() {
  master.begin();
  motor.attach(0, master);
  motor.setCiA402Mode(CIA402_PV_MODE); 
  
  /* RxPDO mapping configuration. */ 
  motor.sdoDownload8(0x1C12, 0x00, 0);
  motor.sdoDownload8(0x1601, 0x00, 0); 
  motor.sdoDownload32(0x1601, 0x01, 0x60400010);
  motor.sdoDownload32(0x1601, 0x02, 0x60FF0020);
  motor.sdoDownload8(0x1601, 0x00, 2); 
  motor.sdoDownload16(0x1C12, 0x01, 0x1601); 
  motor.sdoDownload8(0x1C12, 0x00, 1); 
  /* TxPDO mapping configuration. */
  motor.sdoDownload8(0x1C13, 0x00, 0); 
  motor.sdoDownload8(0x1A01, 0x00, 0);
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010);
  motor.sdoDownload32(0x1A01, 0x02, 0x606C0020); 
  motor.sdoDownload8(0x1A01, 0x00, 2); 
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01);
  motor.sdoDownload8(0x1C13, 0x00, 1); 
  
  master.attachCyclicCallback(MyCyclicCallback); 
  master.start(1000000);
  
  motor.enable(); 
  motor.pv_SetMotionProfileType(0);
  motor.pv_SetAcceleration(5000); 
  motor.pv_SetDeceleration(5000); 
} 

void loop() {
  // ...
}

3.5 Profile Torque (tq) control

Implement torque control on a CiA 402 EtherCAT SubDevice supporting Profile Torque mode (tq).

• Maintain a positive torque of 50 units for 3 seconds.
• Maintain a negative torque of 50 units for 3 seconds.

Here is the example code.

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_CiA402 motor;

void setup() {
  master.begin();
  motor.attach(0, master); 
  motor.setCiA402Mode(CIA402_TQ_MODE);
  master.start(); 
  
  motor.enable();
  motor.tq_SetTorqueProfileType(0);
  motor.tq_SetTorqueSlope(200);
  motor.tq_SetMotorRatedTorque(0);
  motor.tq_SetMotorRatedCurrent(0); 
} 

void loop() {
  motor.tq_Run(50);
  while (motor.tq_IsTargetReached() == 0);
  delay(3000);
  
  motor.tq_Run(-50);
  while (motor.tq_IsTargetReached() == 0);
  delay(3000); 
}

3.6 Profile Torque (tq) control in cyclic callback

Implement torque control on a CiA 402 EtherCAT SubDevice supporting Profile Torque mode (tq).

• Maintain a positive torque of 50 units for 3 seconds.
• Maintain a negative torque of 50 units for 3 seconds.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 6071h: Target torque
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 6077h: Torque actual value

Here is the example code.

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_CiA402 motor;

int toggle = 0;
int cycle_count = 3000;

void MyCyclicCallback()
{
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED) 
    return;
  
  if (++cycle_count < 3000)
    return;
  
  cycle_count = 0;
  toggle = !toggle;
  motor.setTargetTorque(50 * toggle - 50 * !toggle);
} 

void setup() {
  master.begin(); 
  motor.attach(0, master); 
  motor.setCiA402Mode(CIA402_TQ_MODE);
  /* RxPDO mapping configuration. */
  motor.sdoDownload8(0x1C12, 0x00, 0);
  motor.sdoDownload8(0x1601, 0x00, 0); 
  motor.sdoDownload32(0x1601, 0x01, 0x60400010);
  motor.sdoDownload32(0x1601, 0x02, 0x60710010);
  motor.sdoDownload8(0x1601, 0x00, 2);
  motor.sdoDownload16(0x1C12, 0x01, 0x1601);
  motor.sdoDownload8(0x1C12, 0x00, 1);
  /* TxPDO mapping configuration. */
  motor.sdoDownload8(0x1C13, 0x00, 0);
  motor.sdoDownload8(0x1A01, 0x00, 0); 
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010);
  motor.sdoDownload32(0x1A01, 0x02, 0x60770010);
  motor.sdoDownload8(0x1A01, 0x00, 2);
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01); 
  motor.sdoDownload8(0x1C13, 0x00, 1); 
  
  master.attachCyclicCallback(MyCyclicCallback);
  master.start(1000000);
  
  motor.enable();
  motor.tq_SetTorqueProfileType(0);
  motor.tq_SetTorqueSlope(200);
  motor.tq_SetMotorRatedTorque(0);
  motor.tq_SetMotorRatedCurrent(0);
} 

void loop() {
  // ... 
}

3.7 Homing (hm) operation

Initiate the homing method 33 operation on a CiA 402 compliant EtherCAT SubDevice.

Here is the example code.

#include "Ethercat.h" 

EthercatMaster master; 
EthercatDevice_CiA402 motor;

void setup() {
  master.begin();
  motor.attach(0, master);
  motor.setCiA402Mode(CIA402_HOMING_MODE);
  master.start();
  
  motor.enable();
  
  motor.hm_SetHomingMethod(CIA402_HM33);
  motor.hm_SetHomeOffset(0);
  motor.hm_SetHomingSpeeds(100, 20);
  motor.hm_SetHomingAcceleration(100); 
  motor.hm_Run();
  while (motor.hm_IsAttained() == CIA402_HM_RUNNING);
}

void loop() {
  // ...
}

3.8 Cyclic synchronous position (CSP) control in cyclic callback

Implement Cyclic Synchronous Position (CSP) control on a CiA 402 EtherCAT SubDevice.

• The target position is incremented by 1,000 units in each cycle.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 607Ah: Target position
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 6064h: Position actual value

Here is the example code.

#include "Ethercat.h" 

EthercatMaster master; 
EthercatDevice_CiA402 motor; 

int32_t position = 0;

void MyCyclicCallback() 
{
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED)
    return; 
  
  motor.setTargetPosition(position += 1000); 
}

void setup() { 
  master.begin();
  
  motor.attach(0, master);
  motor.setDc(1000000);
  motor.setCiA402Mode(CIA402_CSP_MODE);
  
  /* RxPDO mapping configuration. */
  motor.sdoDownload8(0x1C12, 0x00, 0); 
  motor.sdoDownload8(0x1601, 0x00, 0); 
  motor.sdoDownload32(0x1601, 0x01, 0x60400010); 
  motor.sdoDownload32(0x1601, 0x02, 0x607A0020);
  motor.sdoDownload8(0x1601, 0x00, 2);
  motor.sdoDownload16(0x1C12, 0x01, 0x1601);
  motor.sdoDownload8(0x1C12, 0x00, 1);
  /* TxPDO mapping configuration. */ 
  motor.sdoDownload8(0x1C13, 0x00, 0);
  motor.sdoDownload8(0x1A01, 0x00, 0); 
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010); 
  motor.sdoDownload32(0x1A01, 0x02, 0x60640020);
  motor.sdoDownload8(0x1A01, 0x00, 2);
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01);
  motor.sdoDownload8(0x1C13, 0x00, 1); 
  
  master.attachCyclicCallback(MyCyclicCallback);
  master.start(1000000, ECAT_SYNC); 
  
  motor.setTargetPosition(position = motor.getPositionActualValue());
  motor.enable();
}

void loop() {
  // ... 
}

3.9 Cyclic synchronous velocity (CSV) control in cyclic callback

Implement Cyclic Synchronous Velocity (CSV) control on a CiA 402 EtherCAT SubDevice.

• The target velocity is incremented by 1 unit each cycle until it reaches 3,000 units.
• The target velocity is decremented by 1 unit each cycle until it reaches -3,000 units.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 60FFh: Target velocity
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 606Ch: Velocity actual value

Here is the example code.

#include "Ethercat.h" 

EthercatMaster master; 
EthercatDevice_CiA402 motor;

int32_t velocity = 0;
int toggle = 0;

void MyCyclicCallback() 
{
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED)
    return;
  
  if (abs(velocity) >= 3000) 
    toggle = !toggle; 
  
  velocity = velocity + toggle - !toggle;
  motor.setTargetVelocity(velocity); 
}

void setup() {
  master.begin();
  motor.attach(0, master);
  motor.setDc(1000000);
  motor.setCiA402Mode(CIA402_CSV_MODE);
  
  /* RxPDO mapping configuration. */
  motor.sdoDownload8(0x1C12, 0x00, 0);
  motor.sdoDownload8(0x1601, 0x00, 0);
  motor.sdoDownload32(0x1601, 0x01, 0x60400010);
  motor.sdoDownload32(0x1601, 0x02, 0x60FF0020);
  motor.sdoDownload8(0x1601, 0x00, 2); 
  motor.sdoDownload16(0x1C12, 0x01, 0x1601); 
  motor.sdoDownload8(0x1C12, 0x00, 1); 
  /* TxPDO mapping configuration. */
  motor.sdoDownload8(0x1C13, 0x00, 0);
  motor.sdoDownload8(0x1A01, 0x00, 0);
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010);
  motor.sdoDownload32(0x1A01, 0x02, 0x606C0020);
  motor.sdoDownload8(0x1A01, 0x00, 2);
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01);
  motor.sdoDownload8(0x1C13, 0x00, 1);
  
  master.attachCyclicCallback(MyCyclicCallback);
  master.start(1000000, ECAT_SYNC); 
  
  motor.setTargetVelocity(0);
  motor.enable(); 
} 

void loop() {
  // ... 
}

3.10 Cyclic synchronous torque (CST) control in cyclic callback

Implement Cyclic Synchronous Torque (CST) control on a CiA 402 EtherCAT SubDevice.

• The target torque is incremented by 1 unit each cycle until it reaches 50 units.
• The target torque is decremented by 1 unit each cycle until it reaches -50 units.

To operate in cyclic callback, the relevant objects must be mapped to PDOs as follows:

• Output PDO (RxPDO)
  • Object 6040h: Controlword
  • Object 6071h: Target torque
• Input PDO (TxPDO)
  • Object 6041h: Statusword
  • Object 6077h: Torque actual value

Here is the example code.

#include "Ethercat.h"

EthercatMaster master; 
EthercatDevice_CiA402 motor; 

int16_t torque = 0;
int toggle = 0;

void MyCyclicCallback()
{ 
  if (motor.getCiA402State() != CIA402_OPERATION_ENABLED) 
    return;
  
  if (abs(torque) >= 50) 
    toggle = !toggle;
  
  torque = torque + toggle - !toggle; 
  motor.setTargetTorque(torque);
} 

void setup() {
  master.begin();
  motor.attach(0, master);
  motor.setDc(1000000); 
  motor.setCiA402Mode(CIA402_CST_MODE); 
  
  /* RxPDO mapping configuration. */
  motor.sdoDownload8(0x1C12, 0x00, 0);
  motor.sdoDownload8(0x1601, 0x00, 0); 
  motor.sdoDownload32(0x1601, 0x01, 0x60400010); 
  motor.sdoDownload32(0x1601, 0x02, 0x60710010);
  motor.sdoDownload8(0x1601, 0x00, 2);
  motor.sdoDownload16(0x1C12, 0x01, 0x1601); 
  motor.sdoDownload8(0x1C12, 0x00, 1);
  /* TxPDO mapping configuration. */
  motor.sdoDownload8(0x1C13, 0x00, 0);
  motor.sdoDownload8(0x1A01, 0x00, 0);
  motor.sdoDownload32(0x1A01, 0x01, 0x60410010);
  motor.sdoDownload32(0x1A01, 0x02, 0x60770010); 
  motor.sdoDownload8(0x1A01, 0x00, 2);
  motor.sdoDownload16(0x1C13, 0x01, 0x1A01);
  motor.sdoDownload8(0x1C13, 0x00, 1);
  
  master.attachCyclicCallback(MyCyclicCallback);
  master.start(1000000, ECAT_SYNC);
  
  motor.setTargetTorque(0);
  motor.enable();
}

void loop() {
  // ... 
}

付録

A.1 エラーリスト

ほとんどの関数では、返される値が0未満の場合、エラーであることを示し、その値はエラー・コードを表します。エラー・コードがある場合は、エラーの原因と修正処置を下記で確認できます。

A.2 エラーの説明と修正処置

エラーコードの詳細と修正処置

A.3  SDO Abort Code

ETG.1000.6に定義されたCoE SDOアボート・コード：

A.4 Data Type

ETG.1000.6で定義されている基本データ型:

A.5  About CiA DSP 402

The CiA DSP 402 represents the standardized CANopen device profile for digital controlled motion products like servo controllers, frequency converters or stepper motors.

All the devices mentioned above use communication techniques which conform to those described in the CiA Draft Standard DS 301 (CANopen Application Layer and Communication Profile). This document should be consulted in parallel to CiA® 402-CANopen Drives and Motion Control Profile.

REFERENCES

1. ISO 7498, 1984, Information Processing Systems – Open Systems Interconnection – Basic Reference Model
2. ISO 11898-1, 1999, Road Vehicles, Interchange of Digital Information – Controller Area Network (CAN) for high-speed Communication
3. CiA DS 301, CANopen Application Layer and Communication Profile, Version 4.02, February 2002
4. CiA DS 401, CANopen Device Profile I/O Modules, Version 2.1, May 2002
5. DRIVECOM Profil Antriebstechnik/Profil 21
6. DRIVECOM Profil Antriebstechnik/Servo 22, Jan. 1994

DEFINITIONS AND ABBREVIATION

A.6  Object Dictionary Entries

All information follows the CiA® 402-CANopen Drives and Motion Control Profile.

A.7  Homing Methods

All information follows the CiA® 402-CANopen Drives and Motion Control Profile.

86Duinoリファレンスのテキストは、Arduinoリファレンスを改変したもので、Creative Commons Attribution-ShareAlike 3.0ライセンスに基づいてライセンスされています。リファレンス内のコードサンプルはパブリックドメインとして公開されています。

For more info and sample requests, please write to info@icop.com.tw最寄りの ICOP Branch、または当社までお問い合わせください Worldwide Official Distributor.