我想找...

搜尋

函式庫參考

目錄

[ 入門指南 ] QEC-M-01 與 OrientalMotor αSTEP AZ 系列 Mini Driver

[教程]

我們很高興宣布推出全新的使用者指南，協助工程師與開發者更有效地將 QEC-M-01（EtherCAT MDevice）搭配 OrientalMotor αSTEP AZ 系列 Mini Driver 使用，以實現高效率的自動化控制。

m01_azmini_bg

為了更好地支援工廠自動化與智慧設備控制，我們最新的指南詳細說明如何使用 QEC-M-01 控制 AZ 系列 Mini Driver，內容包含逐步設定流程、詳細的程式範例，以及故障排除建議。

1. 新指南亮點

QEC-M-01 是一款多功能的 EtherCAT MDevice，搭配 OrientalMotor AZ 系列 Mini Driver 使用時，可提供簡單且高效率的自動化解決方案。

AZ 系列 Mini Driver 配備絕對值編碼器，並支援混合伺服控制技術，可避免傳統步進馬達常見的失步問題，同時維持優異的精度與快速響應。AZ 系列 Mini Driver 不僅體積小、易於安裝，也具備高效率，適用於各種精密控制應用，例如：

  • 自動化生產線：用於工廠中驅動機械手臂或分揀系統，提供精準且快速的運作，以提升生產效率。
  • 精密加工設備：可在 CNC 加工及其他精密機械作業中，確保切削、鑽孔與加工過程穩定且精準。

如需更多產品詳細資訊，請參考 OrientalMotor 官方網站：αSTEP AZ 系列 Mini Driver。

1.1 入門指南的優點

  • 逐步設定指南:
    無論您是初學者還是經驗豐富的開發者，我們的指南都能協助您正確連接並設定 QEC-M-01 與 AZ 系列 Mini Driver。
  • 程式範例：:
    本指南包含 Cyclic Synchronous Position（CSP）模式與 Profile Position（PP）模式的詳細程式範例，協助您實現從精準定位到彈性控制等各種應用。
  • 應用場景：:
    憑藉其精巧設計與高精度，AZ 系列 Mini Driver 特別適用於機械手臂控制、包裝與分揀系統，以及 CNC 加工。

2. 開始使用 QEC-M-01 與 AZ 系列 Mini Driver

無論您是初學者還是專業開發者，我們的指南都能提供您必要的支援，協助您順利開始使用 QEC-M-01 與 AZ 系列 Mini Driver。以下提供兩個範例程式，分別展示 PP 模式與 CSP 模式。

2.1 Profile Position（PP）模式

以下範例將 AZ-mini driver 設定為以 CiA 402 Profile Position（PP）模式運作，設定如下：

  • EtherCAT 週期時間：1 ms
  • EtherCAT 模式：ECAT_SYNC
  • Distributed Clocks：停用（依循 EtherCAT 週期時間）

在此程式碼中，EthercatMaster 物件 master 代表 QEC-M-01，而 EthercatDevice_CiA402 物件 az_mini 代表 AZ-mini driver。

#include "Ethercat.h"
#define CYCTIME 1000000

EthercatMaster master;
EthercatDevice_CiA402 az_mini;

int pp_state = 0, pos = 0;

void MyCyclicCallback() {
  pos = az_mini.driveGetPositionActualValue();
}

void setup() {
  Serial.begin(115200);

  Serial.print("Begin: "); Serial.println(master.begin());
  Serial.print("Attach: "); Serial.println(az_mini.attach(0, master));
  az_mini.setDc(1000000);
  az_mini.setCiA402Mode(CIA402_PP_MODE);

  master.attachCyclicCallback(MyCyclicCallback);
  Serial.print("Start: "); Serial.println(master.start(1000000, ECAT_SYNC));
  delay(100);

  Serial.print("Enable: "); Serial.println(az_mini.enable());
  az_mini.pp_SetMotionProfileType(0);
  az_mini.pp_SetVelocity(100000);
  az_mini.pp_SetAcceleration(100000);
  az_mini.pp_SetDeceleration(100000);
  delay(1000);
}

void loop() {
  Serial.print("Pos: ");  Serial.println(pos);

  switch (pp_state) {
    case 0:
      if (az_mini.pp_Run(100000) == 0)
        pp_state++;
      break;
    case 1:
      if (az_mini.driveIsTargetReached())
        pp_state++;
      break;
    case 2:
      if (az_mini.pp_Run(-100000) == 0)
        pp_state++;
      break;
    case 3:
      if (az_mini.driveIsTargetReached())
        pp_state = 0;
      break;
  }

  delay(100);
}

2.2 Cyclic Synchronous Position（CSP）模式

以下範例將 AZ-mini driver 設定為以 CiA 402 Cyclic Synchronous Position（CSP）模式運作，設定如下：

  • EtherCAT 週期時間：1 ms
  • EtherCAT 模式：ECAT_SYNC
  • Distributed Clock：啟用。依循週期時間。

在此程式碼中，EthercatMaster 物件 master 代表 QEC-M-01，而 EthercatDevice_CiA402 物件 az_mini 代表 AZ-mini driver。

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_CiA402 az_mini;

int32_t position = 0;

void MyCyclicCallback() {
  if (az_mini.getCiA402State() != CIA402_OPERATION_ENABLED)
    return;
  az_mini.setTargetPosition(position += 10);
}

void setup() {
  Serial.begin(115200);

  Serial.print("Begin: "); Serial.println(master.begin());
  Serial.print("Attach: "); Serial.println(az_mini.attach(0, master));
  az_mini.setDc(1000000);
  az_mini.setCiA402Mode(CIA402_CSP_MODE);

  master.attachCyclicCallback(MyCyclicCallback);
  Serial.print("Start: "); Serial.println(master.start(1000000, ECAT_SYNC));
  delay(100);

  az_mini.setTargetPosition(position = az_mini.getPositionActualValue());
  Serial.print("Enable: "); Serial.println(az_mini.enable());
  delay(1000);
}

void loop() {
  Serial.print("Pos: "); Serial.println(position);
}

如需進一步了解，請點擊以下連結查看完整指南：

我們將持續提供創新的自動化控制解決方案，以更好地滿足您的應用需求。期待與您攜手邁向更智慧、更高效率的自動化世界。

如需更多資訊或申請樣品，請寄信至 info@icop.com.tw，聯絡離您最近的 ICOP 分公司，或與我們的 全球官方代理商 聯繫。

聯絡 QEC
聯絡 QEC
返回頂端