我想找...

搜尋

函式庫參考

目錄

[ 入門指南 ] QEC-M-01 與 QEC HID 模組（RS-232/485、Keypad、LCM、MPG）

[教程]

本頁為 QEC-M-01 搭配 QEC HID 模組使用的入門指南，內容涵蓋 RS-232/485、Keypad、LCM、MPG、配線、EtherCAT 設定與程式碼範例。

我們很高興分享全新的技術入門指南，協助工程師與系統整合商將 QEC-M-01（EtherCAT MDevice） 搭配 QEC HID 系列（QEC-RXXHU） 進行啟動與整合。QEC HID 系列是基於 EtherCAT 的模組，整合 RS-232/485、Keypad、LCM 與 MPG（手輪） 功能，適用於自動化控制。

QEC_HID

這些指南提供實用的逐步流程，從配線、EtherCAT 啟動，到程式碼範例與整合注意事項，協助您加速調機並減少工程開發時間。

1. 系統概述

1.1 關於 QEC MDevice

QEC-M-01 是一款小巧且高效能的 EtherCAT MDevice，專為確定性控制與快速整合而設計。透過開源的 86Duino IDE，它提供熟悉的開發體驗，並搭配即時架構與整合式工具。

透過 EtherCAT PDO/SDO 資料交換，QEC-M-01 可透過 EtherCAT 網路與 QEC HID 模組可靠地通訊，並交換 UART（RS-232/485）、Keypad、LCM 與 MPG 資料。

QEC HID 系列（QEC-RXXHU）的優點

QEC HID 系列是一款工業級 EtherCAT gateway 模組，整合豐富功能，可滿足 序列通訊連接 與 操作介面 的需求。主要優點包括：

  • 兩組標準 UART 介面，具備 ESD 保護，支援 RS-232 或 RS-485 裝置連接
  • MPG jog（手搖輪），可方便進行遠端寸動／操作（例如：機器人／機械手臂控制）
  • Keypad 輸入 + LCM 顯示，可用於參數輸入、狀態顯示與資料視覺化
QEC_HID-1

2. 您將獲得的內容（入門指南重點）

QEC_HID-2

這些入門指南是依據實際工程流程而設計，內容包含：

  • 逐步設定指南：
    配線、EtherCAT 網路啟動，以及建議檢查清單
  • 程式範例：
    RS-232/485、MPG、Keypad 與 LCM 的實用程式碼片段
  • 整合技巧與疑難排解：
    常見現場問題與圖形化工具的注意事項

2.1 序列 COM Port（RS232/485）

在本節中，我們將讀取 86Duino IDE 中 Serial Monitor 的資料，並將資料從 COM1（RS-232）傳送至 COM2（RS-232）。當 COM2 接收到資料後，再將其列印到 Serial Monitor 上。

以下程式設定：

  • EtherCAT 週期時間：1 毫秒。
  • EtherCAT 模式： ECAT_SYNC。

這個 EthercatMaster 物件 ("master”) 代表 QEC-M-01，而 EthercatDevice_QECR11HU9S 物件 ("slave0”) 代表 QEC-R11HU9S

範例程式碼如下：

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_QECR11HU9S slave0;

int incomingByte = 0;
char read_ch;

void setup() {
  Serial.begin(115200);

  master.begin();
  slave0.attach(0, master);
  master.start(1000000, ECAT_SYNC);

  slave0.uartSetBaud(COM1, 115200);
  slave0.uartSetFormat(COM1, SERIAL_8N1);
  slave0.uartSetBaud(COM2, 115200);
  slave0.uartSetFormat(COM2, SERIAL_8N1);
}

void loop() {
  if (Serial.available() > 0) {
    incomingByte = Serial.read();
    slave0.uartWrite(COM1, incomingByte);

    while (slave0.uartQueryRxQueue(COM2) < 1)
      slave0.update();

    if ((read_ch = (char)slave0.uartRead(COM2)) > 0) {
      Serial.print("COM2 receive: ");
      Serial.println(read_ch);
    }
  }
}

2.2 Keypad + LCM

在本節中，我們將讀取 Keypad 輸入，並將其顯示在 LCM 的指定位置。每當按下按鍵時，蜂鳴器會發出提示音。

以下程式設定：

  • EtherCAT 週期時間：1 毫秒。
  • EtherCAT 模式： ECAT_SYNC。

這個 EthercatMaster 物件 ("master”) 代表 QEC-M-01，而 EthercatDevice_QECR11HU9S 物件 ("slave0”) 代表 QEC-R11HU9S

範例程式碼如下：

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_QECR11HU9S slave0;

int lcmY = 1;

void setup() {
  master.begin();
  slave0.attach(0, master);
  master.start(1000000, ECAT_SYNC);

  slave0.keypadClear();
  slave0.lcmClear();
}


void loop() {
  char keyPadInput = slave0.keypadRead();

  if (keyPadInput >= '0' && keyPadInput <= '9') {
    slave0.lcmGotoXY(keyPadInput - '0' + 1, lcmY);
    slave0.lcmWrite(keyPadInput);
  } else if (keyPadInput >= 'A' && keyPadInput <= 'D') {
    slave0.lcmGotoXY(keyPadInput - 'A' + 11, lcmY);
    slave0.lcmWrite(keyPadInput);
  } else if (keyPadInput == '#') {
    lcmY = 1;
    slave0.lcmClear();
  } else if (keyPadInput == '*') {
    lcmY = 2;
    slave0.lcmClear();
  }

  if (keyPadInput != 0) slave0.buzzer(3000, 200);

  slave0.update();
}

2.3 MPG 手搖輪

在本節中，我們將讀取 QEC-R11HU9S 的 MPG 資料與狀態，並透過 86Duino IDE 的 Serial Monitor 輸出 EMG、Enable、Axis、Ratio、Raw 與 Logical 資料。

以下程式設定：

  • EtherCAT 週期時間：1 毫秒。
  • EtherCAT 模式： ECAT_SYNC。

這個 EthercatMaster 物件 ("master”) 代表 QEC-M-01，而 EthercatDevice_QECR11HU9S 物件 ("slave0”) 代表 QEC-R11HU9S

範例程式碼如下：

#include "Ethercat.h"

EthercatMaster master;
EthercatDevice_QECR11HU9S slave0;

void setup() {
  Serial.begin(115200);

  master.begin();
  slave0.attach(0, master);
  master.start(1000000, ECAT_SYNC);
}

void loop() {
  // Read various parameters from the slave and print them
  Serial.print("EMG: ");
  Serial.print(slave0.mpgReadEmergencyStop()); // Read and print the emergency stop status
  Serial.print(", Enable: ");
  Serial.print(slave0.mpgReadEnableSwitch()); // Read and print the enable switch status
  Serial.print(", Axis: ");
  Serial.print(slave0.mpgReadAxis()); // Read and print the axis information
  Serial.print(", Ratio: ");
  Serial.print(slave0.mpgReadRatio()); // Read and print the ratio
  Serial.print(", Raw: ");
  Serial.print(slave0.mpgReadEncoderRaw()); // Read and print the raw encoder value
  Serial.print(", Logical: ");
  Serial.println(slave0.mpgReadEncoder()); // Read and print the logical encoder value

  slave0.update();
}

如需進一步了解，請點擊以下連結查看完整指南：

如果您正在建置需要 EtherCAT gateway 來實現 序列通訊連接 與 操作介面整合 的自動化系統，將 QEC-M-01 搭配 QEC HID（QEC-RXXHU）系列 可提供實用的解決方案。透過 EtherCAT PDO/SDO 資料交換，MDevice 可透過 EtherCAT 網路與 QEC HID 模組穩定交換 UART（RS-232/485）、Keypad、LCM 與 MPG 資料。

如需更多資訊或樣品申請，請寄信至  info@icop.com.tw、致電最近的 ICOP 分支機構，或聯絡我們的全球官方經銷商。

聯絡 QEC
聯絡 QEC
返回頂端